ansys边坡程序

bailing030

         /prep7
et,1,plane42
keypot,1,3,2
mp,ex,1,20e9             !岩体参数
mp,prxy,1,0.22
mp,dens,1,2600
mp,ex,2,3e9                !滑体参数
mp,prxy,2,0.35
mp,dens,2,2140
mp,ex,3,2.7e9             !35%饱和度
mp,prxy,3,0.35
mp,dens,3,2180
mp,ex,4,2.4e9             !50%饱和度
mp,prxy,4,0.35
mp,dens,4,2210
mp,ex,5,2.1e9             !65%饱和度
mp,prxy,5,0.35
mp,dens,5,2240
mp,ex,6,1.8e9            !80%饱和度
mp,prxy,6,0.35
mp,dens,6,2270
mp,ex,7,1.5e9             !100%饱和度
mp,prxy,7,0.35
mp,dens,7,2300
save
k,1,0,0,0
k,2,0,505,0
k,3,562,505,0
k,,621,459,0
k,,658,433,0
k,,693,393,0
k,,802,313,0
k,,850,303,0
k,,892,273,0
k,,913,253,0
k,,930,243,0
k,,1034,233,0
k,,1186,228,0
k,,1216,223,0
k,,1232,208,0
*do,i,1,14
l,i,i+1
*enddo
k,16,660,387,0
k,,770,248,0
k,,827,230,0
k,,888,217,0
k,,930,216,0
k,,1034,213,0
k,,1186,209,0
l,4,16
l,16,17
l,17,18
l,18,19
l,19,20
l,20,21
l,21,22
l,22,15
nummrg,all
numcmp,all
k,23,1243,198,0
k,,612,380,0
k,,745,214,0
k,,884,181,0
k,,1242,174,0
l,3,24
l,24,25
l,25,26
l,26,27
l,27,23
l,23,15
nummrg,all
numcmp,all
k,28,1610,198,0
k,,1610,0,0
k,,1243,0,0
k,,884,0,0
k,,745,0,0
k,,612,0,0
l,6,16
l,7,17
l,8,18
l,9,19
l,11,20
l,13,22
l,16,24
l,17,25
l,19,26
l,24,33
l,25,32
l,26,31
l,27,30
l,1,33
l,30,31
l,31,32
l,32,33
l,23,28
l,28,29
l,29,30
save
al,4,5,15,29
al,29,6,16,30
al,7,17,30,31
al,8,18,31,32
al,9,10,19,32,33
al,11,12,20,21,33,34
al,13,14,22,34
al,3,15,35,23
al,35,16,24,36
al,36,17,18,37,25
al,19,20,21,22,26,27,28,37
al,1,2,23,38,42
al,38,39,24,45
al,39,40,25,44
al,40,41,26,43
al,46,47,48,27,41
allsel,all                    !选择所有元素
type,1
mat,1
mshape,1,2d
mshkey,0                 !设置划分方式，自由划分
esize,10,0
amesh,1,11,1
esize,,,
allsel,all
amesh,12,16,1
save
finish
!施加边界条件，并进行求解设置
/solu
eplot
save
nsubst,20           !指定荷载子步
nlgeom,on
nropt,full
pred,on
lnsrch,on
outres,all,last
!施加约束条件
nsel,s,loc,x,0
d,all,ux
nsel,s,loc,x,1610
d,all,ux
nsel,s,loc,y,0
d,all,all
allsel,all
acel,0,10,0
allsel,all
save
finish
!求解自重应力场
/solu
time,1
asel,s,,,1,7,1
esla,s
mpchg,2,all
allsel,all
solve
save
finish
!求解不同饱和度下的应力场
!35%饱和度
/solu
antype,,rest
time,2
asel,s,,,1,7,1
esla,s
mpchg,3,all
allsel,all
solve
save
finish
!50%饱和度
/solu
antype,,rest
time,3
asel,s,,,1,7,1
esla,s
mpchg,4,all
allsel,all
solve
save
finish
!65%饱和度
/solu
antype,,rest
time,4
asel,s,,,1,7,1
esla,s
mpchg,5,all
allsel,all
solve
save
finish
!80%饱和度
/solu
antype,,rest
time,5
asel,s,,,1,7,1
esla,s
mpchg,6,all
allsel,all
solve
save
finish
!100%饱和度
/solu
antype,,rest
time,6
asel,s,,,1,7,1
esla,s
mpchg,7,all
allsel,all
solve
save
finish
!初始状态下边坡稳定分析
/post1
set,1
plnsol,s,y,0,1          !初始状态下自重应力场
plnsol,u,y,0,1         !初始状态下位移场
                     plnsol,s,xy,0,1          !初始状态下剪应力
plnsol,epto,xy,0,1 !初始状态下剪应变
!荷载工况
/post1
lcdef,1,1,          !将第一个计算步定义为工况1
lcdef,2,6,          !将第六个计算步定义为工况2
lcase,2,              !读入荷载工况2
lcoper,sub,1,,,        !将荷载工况2减去工况1
!绘制位移、剪力、剪应变增量图
plnsol,u,y,0,1         !初始状态下位移场
plnsol,s,xy,0,1        !初始状态下剪应力
plnsol,epto,xy,0,1 !初始状态下剪应变
!采用mohr-column准则对饱水状态下的塑性区分布进行计算，C=50kPa，内摩擦角30度
/post1
asel,s,,,1,7,1
esla,s
etable,s1_1,s,1     !将所选单元的第1,3主应力定义为单元表
etable,s3_1,s,3
sadd,s1,s3_1,,-1.00,1
sadd,s3,s1_1,,-1.00,1
sadd,smf_over,s1,s3,1.00,-1.00
cos_fai=cos(30/180*3.1415926)       !计算内摩擦角的余弦
sin_fai=sin(30/180*3.1415926)
constant=2*50000*cos_fai
sadd,s1_s3,s1,s3,1,1
sexp,s1_s3,s1_s3,,1
sadd,smf_down,s1_s3,,sin_fai,,constant
sexp,s_m_f,smf_over,smf_down,1,-1
esel,all
/contour
pletab,s_m_f,avg  !绘制屈服单元的云图